'
'*************************************************************************************************************
'* This source code is provided 'as is' and any express or implied warranties, including,                    *
'* but not limited to, the implied warranties of merchantability and fitness for a particular                *
'* purpose are disclaimed.                    *
'*                    *
'* In no event shall the author, Crownhill or contributers be liable for any direct, indirect, incidental,   *
'* special, exemplary, or consequential damages (including, but not limited to,  procurement of substitute   *
'* goods or services; loss of use, data, or profits;  or business interruption) however caused and on any    *
'* theory of liability, whether in contract, strict liability, or tort (including negligence or otherwise)   *
'* arising in any way out of the use of this source code, even if advised of the possibility of such damage. *
'*                    *
'* Any views and conclusions contained in the source code and any documentation are those of the author's    *
'* and should not be interpreted as representing official policies,                    *
'* either expressed or implied, of Crownhill Associates Ltd.                    *
'*************************************************************************************************************
'
' Program BARGRAF2.BAS
' This program generates a horizontal bargraph
' with a 2x16 Intelligent LCD Display.

      Include "Proton_4.Inc"

' ** Declare Variables **
      Dim Bar_Val As Byte                 ' Value to be graphed.
      Dim Bars As Byte                 ' Number of full ||| bars to draw.
      Dim Balance As Byte                 ' Balance left after all |||s are drawn.
      Dim Balf As Byte                 ' Is a 'Balance' character needed? (1=yes, 0=no).

' ** Declare Constants **
      Symbol B_Wdth = 16                  ' Max width in characters of bar.
      Symbol MaxBar = B_Wdth * 3          ' Max bar counts.
      Symbol FullBar = 3                  ' ASCII value of ||| bar.
      Symbol BaseBar = 0                  ' ASCII value of 0 bar (blank).
      Symbol CGRAM = 64
'-------------------------------------------------------------------------------

      DelayMS 100
      Cls
' Create the bit patterns that make up the bars in the LCD's CGRAM.
' The vertical bars are made up of 8 identical bit patterns
' A | bar consists of 5 times %10000,
' A || bar consists of 5 times %10100
' A ||| bar consists of 5 times %10101

      Print $FE,CGRAM,Rep $0\8,$0,Rep $10\6,$0,$0,Rep $14\6,$0,$0,Rep $15\6
      GoTo Over_Bargraph                    ' Jump over the subroutine
'-------------------------------------------------------------------------------
' The value in 'Bar_Val' is displayed as a horizontal bar graph
' from the current cursor location with a total width (in characters) set by the B_WDTH constant.
' Each character position can represent a maximum value of 3 using the Fullbar character |||.
' The routine calculates how many full bars to use by dividing by 3.
' If there is a remainder after dividing by 3, the routine joins on a partial-bar character
' ( | or ||) to represent the balance.
' Then it pads out the remainder of the bar width with spaces to erase any leftover bars
BarGraph:
      If Bar_Val > MaxBar Then Return             ' Check boundaries
      Bars = Bar_Val / 3                          ' One full bar for each 3 graph units.
      Balance = Bar_Val // 3                      ' Balance is the remainder after a division by 3.
      If Balance > 1 Then Balance = 1
      Balf = Balance
      Print At 1,1,Rep FullBar\Bars,Rep (Balance + BaseBar)\Balf,Rep " " \B_Wdth - (Bars + Balf)
      Print At 2,1,Dec Bar_Val,"  "               ' Display the decimal value of BAR_VAL
      Return
'-------------------------------------------------------------------------------
' Demonstration routine
Over_Bargraph:
      For Bar_Val = 0 To 40
          GoSub BarGraph
          DelayMS 100
      Next
      For Bar_Val = 40 To 0 Step -1
          GoSub BarGraph
          DelayMS 100
      Next
      GoTo Over_Bargraph