'****************************************************************
'*  Name    : MCP41xxx_test.PBP
'*  Date    : 2/8/06
'*  Version : 1.0
'*  Notes   : PIC16F84A
'****************************************************************
'
' LCD should be connected as follows:
'       LCD     PIC
'       DB4     PortA.0
'       DB5     PortA.1
'       DB6     PortA.2
'       DB7     PortA.3
'       RS      PortA.4 (add 4.7K pullup resistor to 5 volts)
'       E       PortB.3
'       RW      PortB.2
'       Vdd     5 volts
'       Vss     Ground
'       Vo      20K potentiometer (or ground)
'       DB0-3   No connect

     include     "modedefs.bas"
      
  DEFINE    LCD_DREG    PORTA
  DEFINE    LCD_DBIT    0
  DEFINE    LCD_RSREG    PORTA
  DEFINE    LCD_RSBIT    4
  DEFINE    LCD_EREG    PORTB
  DEFINE    LCD_EBIT    3
  DEFINE    LCD_RWREG    PORTB
  DEFINE    LCD_RWBIT    2
  DEFINE    LCD_BITS    4
  DEFINE    LCD_LINES    2
  DEFINE    LCD_COMMANDUS    2000
  DEFINE    LCD_DATAUS    50

     define  BUTTON_PAUSE 50

'                    Digital POT connections:
cs_pin      var portb.0   ' pin 1 on MCP41XXX
clock_pin   var porta.1   ' pin 2 on MCP41XXX
data_pin    var porta.0   ' pin 3 on MCP41XXX

'           Control buttons:
up_button   var portb.4
dwn_button  var portb.5

'           LED indicators:
green_led   var portb.1

b0          var byte      ' BUTTON working variable
b1          var byte
position    var byte      ' default wiper position value
max_wip     var byte      ' maximum wiper position value
min_wip     var byte      ' minimum wiper position value
command     var byte                 
wiper       var byte   

operate     con     %11011111
shutdown    con     %11101111   

             wiper = 127
             b0 = 0
             b1 = 0
             min_wip = 0
             max_wip = 255
             command = operate
             high cs_pin
             pause 500

             goto display
              
begin:      pause 1
             button up_button,0,100,5,b0,0,continue
             if wiper < max_wip then
                 low green_led
                 wiper = wiper + 1
             else
                 high green_led
             endif
             goto display            
continue:   button dwn_button,0,100,5,b1,0,begin
             if wiper > min_wip then
                 low green_led
                 wiper = wiper - 1
             else
                 high green_led
             endif
display:    lcdout $FE,1,#wiper
             low cs_pin
             shiftout data_pin,clock_pin,1,[command,wiper]
             high cs_pin
             goto begin
             end