program FrequencyCounter

dim T0Count  as byte
      txt      as char[20]
      Freq,
      Old_Freq,
      Tmp_Freq as word

sub procedure Interrupt
    INTCON.GIE = 0                       ' DISABLE INTERRUPTS
    if TestBit(INTCON, TMR0IF) = 1 then  ' Test if timer0 interrupt has occurred
        inc(T0Count)
        if T0Count = 4 then              ' 1s has elapsed
            Freq = Tmp_Freq              ' copy current value to display container
            Tmp_Freq = 0                 ' reset current value
            T0Count = 0
            TMR0H     = $2F              ' these values are calculated for 8MHz
            TMR0L     = $6C
        end if
        ClearBit(INTCON, TMR0IF)         ' clear interrupt flag
    else                    ' this is external interrupt on rising edge
         Inc(Tmp_Freq)                   ' increment pulse counter
         ClearBit(INTCON, INT0IF)        ' clear interrupt flag
    end if
    INTCON.GIE = 1                       ' ENABLE INTERRUPTS
end sub

main:
    TRISB = $0F                          ' PORTB is half input, half output
    Lcd8_Config(PORTB, PORTD,            ' LCD is connected in 8bit mode
                4, 6, 5,                 ' Control pins on PORTB
                7, 6, 5, 4, 3, 2, 1, 0)  ' Data pins on PORTD
    Lcd8_Cmd(LCD_CLEAR)                  ' Clear LCD
    Lcd8_Cmd(LCD_CURSOR_OFF)             ' Turn cursor OFF
    Lcd8_Out(1, 1, "Frequency (Hz):")    ' Write static text
      
    Freq      = 0                        ' Initialize global vars
    Old_Freq  = 1                        ' Force first write
    T0Count   = 0

    TMR0H     = $2F                      ' Pre-load Timer0:
    TMR0L     = $6C                      '    these values are calculated for 8MHz
    T0CON     = $02                      ' Timer0: internal clock, prescaler 1:8, 16bit mode

    INTCON2.INTEDG0 = 1                  ' Interrupt on rising edge on RB0
    INTCON2.TMR0IP  = 0                  ' Timer0 interrupt is of low priority- not really important
      
    T0CON.TMR0ON = 1                     ' Start Timer0
    INTCON       = $F8                   ' Enable TMR0 interrupt,
                     '   peripheral interrupts,
                     '   interrupt on PORTB and
                     '   external interrupt INT0
                    
                    
    while true                           ' Repeat endlessly
       if Freq <> Old_Freq then          ' Dislay measurements only when there is change.
            WordToStr(Freq, txt)         ' Convert new value to string
            Lcd8_Out(2, 5, txt)          ' Display new value in the second row
            Old_Freq = Freq              ' Signal that the current value has been shown
            '** you can do some other processing with Freq,
            '** for example to send it to PC via USART.
      end if
    wend
end.